modules/home-manager/personal/programs/git.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

{ config, lib, pkgs, ... }@extraArgs:

let
  primaryEmail = let
    primaryEmailList = builtins.filter (account: account.primary)
      (lib.attrValues config.accounts.email.accounts);
  in if primaryEmailList == [ ] then {
    userName = lib.mkDefault "Quentin Aristote";
    address = lib.mkDefault "quentin@aristote.fr";
  } else
    builtins.head primaryEmailList;
in {
  programs.git = {
    userName = primaryEmail.userName;
    userEmail = primaryEmail.address;
    signing = lib.mkIf (primaryEmail ? "gpg") {
      inherit (primaryEmail.gpg) key signByDefault;
    };

    ignores = builtins.map builtins.readFile
      (with pkgs.personal.static.gitignore; [ direnv emacs linux ]) ++ [
        # Personal rules
        ''
          # Nix
          shell.nix
          .nix-gc-roots
          .tmp
          result
        ''
      ];

    extraConfig = {
      safe.directory = lib.mkIf (extraArgs ? osConfig) (
        let 
          flake = extraArgs.osConfig.system.autoUpgrade.flake;
          flakeIsValid = flake != null && lib.hasPrefix "git+file://" flake;
          flakePath = lib.removePrefix "git+file://" flake;
         in lib.optional flakeIsValid flakePath);
    };
  };
}